Matrixfunktioner

Indhold

# Matrix-funktioner

Denne kategori indeholder matrixfunktioner.

## Hvad er en matrix?

En matrix er et sammenkædet celleområde i et regneark, som indeholder værdier. Et område af 3 rækker og 3 kolonner er en 3 x 3 matrix:

| A | B | C | D | E
1 | 7 | 31 | 33
2 | 95 | 17 | 2
3 | 5 | 10 | 50
4

Den mindst mulige matrix er en 1 x 2 eller 2 x 1 tabel med to tilstødende celler.

## Hvad er en matrixformel?

En formel i hvilken de enkelte værdier i et celleområde er valideret refereres til som en matrixformel. Forskellen mellem en matrixformel og andre formler er, at matrixformlen håndterer adskillige værdier samtidigt i stedet for kun én.

En matrixformel kan ikke alene bearbejde adskillige samtidige værdier, men også returnere adskillige værdier. Resultater fra en matrixformel er også en matrix.

For at gange værdierne i de enkelte celler med 10 i den ovenstående tabel, behøver du ikke at anvende en formel til hver celle eller værdi. I stedet kan du bare bruge en enkelt matrixformel. Marker et område på 3 x 3 celler et andet sted i regnearket, indtast formlen =10*A1:C3 og bekræft med tastekombinationen KommandoCtrl + Skift + Enter. Resultatet er en 3 x 3 matrix, hvor de enkelte værdier i celleområdet (A1:C3) er ganget med faktor 10.

Ud over multiplikation kan du også bruge andre operatorer på referenceområdet (en matrix). Med LibreOffice Calc kan du lægge til (+), trække fra (-), gange (*), dividere (/), bruge eksponenter (^), sammentrækning (&) og sammenligninger (=, <>, <, >, <=, >=). Operatorerne kan bruges på hver enkelt værdi i celleområdet og returnerer resultatet som en matrix, hvis matrixformlen blev indtastet.

Sammenligningsoperatorer i en matrixformel behandler tomme celler på samme måde som i normale formler; det vil sige enten som 0 eller som en tom streng. Hvis for eksempel cellerne A1 og A2 er tomme, vil både matrixformlerne {=A1:A2=""} og {=A1:A2=0} returnere en 1-kolonne 2-rækkers matrix med celler, der indeholder SAND.

### Hvornår skal du bruge matrixformler?

Brug matrixformler hvis du skal gentage beregninger på flere forskellige værdier. Hvis du senere beslutter at ændre beregningsmetoden, skal du kun ændre matrixformlen. For at tilføje en matrixformel skal du vælge hele matrixområdet og derefter foretage de relevante ændringer i matrixformlen.

Matrixformler er også en måde at spare plads på, når adskillige værdier skal beregnes, idet de ikke er særligt hukommelseskrævende. Matricer er desuden et væsentligt værktøj til at udføre komplekse beregninger, fordi du kan have flere celleområder indeholdt i din beregning. LibreOffice har forskellige matematiske funktioner til brug for matricer såsom funktionen MPRODUKT (på engelsk: MMULT), der ganger to matricer eller funktionen SUMPRODUKT (på engelsk: SUMPRODUCT), der beregner skalarproduktet af to matricer.

## Brug af matrixformler i LibreOffice Calc

### Implicit fællesmængde af matrixformler

Du kan også lave en "normal" formel, hvor referenceområdet (for eksempel parametre) angiver en matrixformel. En sådan formel kaldes også en "implicit fællesmængde" af matrixformel. Resultatet hentes fra fællesmængden (skæringen) mellem referenceområdet og de rækker eller kolonner, hvor formlen findes. Hvis der ikke er nogen skæring, eller hvis fællesmængden indeholder flere rækker eller kolonner, så bliver fejlen #VÆRDI! vist. Det følgende eksempel viser princippet:

I tabellen ovenfor, anbring matrixformlen i D1:

{=A1:A3 + 100}

Cellerne D1, D2, D3 har værdier henholdsvis 107, 195, 105.

Indsæt følgende formel i E2, skriv ikke ind som matrixformel.

=A1:A3 + 100

Cellerne E1 og E3 er tomme, celle E2 har værdien 195. Dette er den implicitte fællesmængde for matrixformler.

Indsæt nedenstående formel i E4, som i E2.

=A1:A3 + 100

Celle E4 viser fejlkoden #VÆRDI!. Række 4 er udenfor området A1:A3 for formlen.

### Opret matrixformler

Hvis du opretter en matrixformel ved hjælp af Funktionsguiden, skal du markere afkrydsningsfeltet Matrix hver gang, så resultaterne returneres i en matrix. Ellers returneres kun værdien i den øverste venstre celle af den beregnede matrix.

Hvis du indtaster matrixformlen direkte i cellen, skal du bruge tastekombinationen Skift + KommandoCtrl + Enter i stedet for Enter-tasten. Kun da bliver formlen en matrixformel.

Matrixformler vises i klammeparenteser (tuborgklammer) i LibreOffice Calc. Du kan ikke oprette matrixformler ved manuelt at indtaste klammeparenteser (tuborgklammer).

Cellerne i en resultat-matrix er automatisk beskyttet mod ændringer. Du kan imidlertid redigere, slette eller kopiere matrixformlen ved at vælge hele matrix-celleområdet.

### Brug af indlejrede områdekonstanter i formler

Calc understøtter indlejrede konstanter af typen matrix/område i formler. Et indlejret område er omgivet af krølleparenteser '{' og '}'. Elementerne kan hver især være et tal (inklusiv negative), en logisk konstant (SAND, FALSK), eller en bogstavelig streng. Ikke konstante udtryk er ikke tilladt. Områder kan indtastes med en eller flere rækker, og en eller flere kolonner. Alle rækker skal indeholde det samme antal elementer, alle kolonner skal indeholde det samme antal elementer.

Kolonneadskilleren (som adskiller elementerne i en række) og rækkeadskilleren er sprogafhængige. I hjælpen er semikolon ';' og pipe '|* brugt til at indikere henholdsvis kolonne- og rækkeadskiller. For eksempel er det i den engelske version ',' som er brugt som kolonneadskiller, mens ';' er brugt som rækkeadskiller.

Du kan se og ændre række- og kolonne-separatorerne i LibreOffice ▸ IndstillingerFunktioner ▸ Indstillinger ▸ Calc ▸ Formler ▸ Separatorer.

Matrixer kan ikke være indlejret.

Eksempler:

={1;2;3}

En matrix med en række bestående af de tre tal 1, 2 og 3.

For at indtaste denne matrixkonstant markerer du tre celler efter hinanden og indtaster så formlen ={1;2;3} med krøllede parenteser og semikoloner, derefter trykker du på KommandoCtrl + Skift + Enter.

={1;2;3|4;5;6}

En matrix med to rækker og tre værdier i hver række.

={0;1;2|FALSK;SAND;"to"}

En blandet datamatrice.

=SIN({1;2;3})

Angivet som en matrixformel, leverer resultatet af tre SIN beregninger med argumenterne 1, 2, og 3.

### Redigering af matrixformler

1. Vælg celleområdet eller matrixen, der indeholder matrixformlen. For at vælge hele matrixen placerer du cellemarkøren i matrixområdet og trykker derefter på KommandoCtrl + /, hvor / er divisions-tasten i det numeriske tastatur (talblokken).

2. Du trykker enten på F2 eller placerer markøren på inputlinjen. Begge disse handlinger lader dig redigere formlen.

3. Når du har lavet ændringer, trykker du på KommandoCtrl + Skift + Enter.

Du kan formatere de forskellige dele af en matrix. For eksempel kan du ændre skrifttype eller farve. Marker et celleområde og ret derefter de indstillinger du ønsker.

### Sletning af matrixformler

1. Vælg celleområdet eller matrixen, der indeholder matrixformlen. For at vælge hele matrixen, placerer du cellemarkøren i matrixområdet og trykker derefter på KommandoCtrl + /, hvor / er divisionstasten i det numeriske tastatur (talblokken).

2. Tryk på Delete for at slette matrixindholdet, herunder matrixformlen, eller tryk på Tilbage og dette åbner dialogfeltet Slet indhold. Vælg Formel eller Slet alt og klik på OK.

### Kopiering af matrixformler

1. Marker celleområdet eller matricen som indeholder matrixformlen.

2. Enten tryk på F2 eller placer markøren i indtastningslinjen.

3. Kopiér formlen ind i input-linjen ved at trykke på KommandoCtrl+C.

4. Vælg et celleområde, hvor du vil indsætte matrixformlen og enten tryk på F2 eller placer markøren på indtastningslinjen.

5. Indsæt formlen ved at trykke på KommandoCtrl + V i det markerede område og bekræft det ved at trykke på KommandoCtrl + Skift + Enter. Det markerede område indeolder nu matrixformlen.

### Justering af et matrixområde

Gør følgende, hvis du vil redigere resultatområdet:

1. Marker celleområdet eller matricen som indeholder matrixformlen.

2. Under markeringen, til højre, ser du et lille ikon, hvormed du kan forstørre eller formindske området ved hjælp af musen.

Når du tilpasser området vil matrixformlen ikke automatisk blive tilpasset. Du har kun ændret det område, hvori resultatet vises.

Ved at holde KommandoCtrl-tasten nede kan du oprette en kopi af matrixformlen i det givne område.

### Betingede matrixberegninger

En betinget matrixberegning er en matrix eller matrixformel, som indeholder en HVIS() eller VÆLG() funktion. Betingelsesargumentet i formlen er en områdereference eller et matrixresultat.

I det følgende eksempel bliver testen >0 i formlen {=HVIS(A1:A3>0; "Ja"; "Nej")} anvendt på hver celle i området A1:A3, og resultatet bliver kopieret til den tilsvarende celle.

| A | B (formel) | B (resultat)
1 | 1 | {=HVIS(A1:A3>0; "Ja"; "Nej")} | Ja
2 | 0 | {=HVIS(A1:A3>0; "Ja"; "Nej")} | Nej
3 | 1 | {=HVIS(A1:A3>0; "Ja"; "Nej")} | Ja

De følgende funktioner tilbyder tvungen matrixhåndtering: KORRELATION, KOVARIANS, PROGNOSE, FTEST, SKÆRING, MDETERM, MINVERT, MPRODUKT, HYPPIGST, PEARSON, SANDSYNLIGHED, FORKLARINGSGRAD, STIGNING, STFYX, SUMPRODUKT, SUMX2MY2, SUMX2PY2, SUMXMY2, TTEST (på engelsk: CORREL, COVAR, FORECAST, FTEST, INTERCEPT, MDETERM, MINVERSE, MMULT, MODE, PEARSON, PROB, RSQ, SLOPE, STEYX, SUMPRODUCT, SUMX2MY2, SUMX2PY2, SUMXMY2, TTEST). Hvis du bruger områdereferencer som argumenter, når du kalder en af disse funktioner, opfører funktionerne sig som matrixfunktioner. Den følgende tabel giver et eksempel på tvungen matrixhåndtering:

| A | B (formel) | B (resultat) | C (tvungen matrixformel) | C (resultat)
1 | 1 | =A1:A2+1 | 2 | =SUMPRODUKT(A1:A2+1) | 5
2 | 2 | =A1:A2+1 | 3 | =SUMPRODUKT(A1:A2+1) | 5
3 |  | =A1:A2+1 | #VÆRDI! | =SUMPRODUKT(A1:A2+1) | 5

## FORØGELSE (på engelsk: GROWTH)

Beregner punkterne på en eksponentiel tendens i en matrix.

#### Syntaks

FORØGELSE( Data Y [; [ Data X ] [; [ Ny data X ] [; Funktionstype ] ] ])

DataY repræsenterer matricen med Y-data.

DataX (valgfri) repræsenterer matricen med X-data.

Nye_data_X (valgfri) repræsenterer den matrix med X-data, hvori værdierne genberegnes.

Funktionstype (valgfri). Hvis Funktionstype = 0, vil funktioner på formen Y = m^x blive beregnet. Ellers bliver Y = B*m^X funktioner beregnet.

I LibreOffice Calc-funktioner kan parametre markeret som "valgfri" kun udelades, hvis ingen parameter følger. I en funktion med for eksempel fire parametre, hvor de sidste to parametre er markeret som "valgfri", kan du udelade parameter 4 eller parametrene 3 og 4, men du kan ikke udelade parameter 3 alene.

Flere forklaringer øverst på denne side.

#### Eksempel

Denne funktion returnerer en matrix og håndteres på den samme måde som andre matrixfunktioner. Marker det område, hvor du vil have svaret vist, og marker funktionen. Marker Data_Y. Indtast en øvrige parametre, marker Matrix og klik på OK.

## FREKVENS (på engelsk: FREQUENCY)

Angiver frekvensfordelingen i en enkeltkolonnematrix. Funktionen tæller antallet af værdier i Data-matricen, som ligger inden for de værdier, der er opgivet af Klasser-matricen.

#### Syntaks

FREKVENS(Data; Grupper)

Data repræsenterer henvisningen til de værdier, som skal tælles.

Grupper repræsenterer matricen med grænseværdierne.

Denne funktion ignorerer al tekst og tomme celle indenfor et dataområde. Hvis du har mistanke om forkerte resultater fra denne funktion, kigger du efter tekst i dataområderne. For at fremhæve tekstindhold i dataområdet bruger du funktionaliteten Fremhæv værdier.

Du kan finde en generel introduktion til matrixfunktioner øverst på denne side.

#### Eksempel

I den følgende tabel lister kolonne A usorterede måledata. Kolonne B indeholder den øvre grænse, som du har indtastet for de grupper, hvori du vil opdele data i kolonne A. I henhold til grænsen indtastet i B1, returnerer FREKVENS-funktionen antal målte værdier mindre end eller lig med 5. Da grænsen i B2 er 10, returnerer FREKVENS-funktionen det andet resultat som antal målte værdier, som er større end 5 og mindre end eller lig med 10. Den tekst, du indtastede i B6, ">25", er kun til referenceformål.

| A | B | C
1 | 12 | 5 | 1
2 | 8 | 10 | 3
3 | 24 | 15 | 2
4 | 11 | 20 | 3
5 | 5 | 25 | 1
6 | 20 | >25 | 1
7 | 16 |  |
8 | 9 |  |
9 | 7 |  |
10 | 16 |  |
11 | 33 |  |

{=FREKVENS(A1:A11;B1:B6)}

Marker et enkelt kolonneområde hvori du indtaster frekvensen i henhold til gruppegrænserne. Du skal vælge et felt mere end klassens øvre grænse. I dette eksempel, vælg området C1:C6. Kald FREKVENS funktionen i Funktionsguiden. Marker det målingsområdet for Data i (A1:A11), derefter en kolonne til Grupper, hvor du indtastede klassebegrænsningerne (B1:B6). Marker afkrydsningsfeltet Matrix og klik OK. Du vil se frekvensantal i det først markerede område C1:C6.

Flere forklaringer øverst på denne side.

## LINREGR (på engelsk: LINEST)

Returnerer en tabel med statistiske oplysninger for en linje som bedst passer til et datasæt.

#### Syntaks

LINREGR( Data Y [; Data X [; Lineær type [; Statistik]]])

DataY er et enkelt række- eller kolonneområde, som angiver y-koordinaterne i et sæt datapunkter.

DataX er et enkelt tilsvarende række- eller kolonneområde, som angiver x-koordinaterne. Hvis DataX udelades, bruges standardværdierne 1, 2, 3, ..., n. Hvis der er mere end et enkelt sæt variable, kan DataX være et område med tilsvarende flere rækker eller kolonner.

LINREGR finder en ret linje y = a + bx som bedst passer data ved hjælp af en lineær regression ("mindste kvadraters" metode). Med mere end et sæt variable er den rette linje af formlen y = a + b1x1 + b2x2 ... + bnxn.

Hvis Linjetype er FALSK vil den rette linje blive tvunget til at gå igennem nulpunktet (konstanten a er nul; y=bx). Hvis undladt, vil Linjetype blive sat til SAND (linjen vil ikke blive tvunget igennem nulpunktet; y=a+bx).

Hvis Statistik er udeladt eller FALSE bliver kun den øverste linje fra statistiktabellen returneret. Hvis TRUE bliver hele tabellen returneret.

LINREGR returnerer en tabel (matrice) med statistik som herunder og skal indsættes som områdeformel (for eksempel ved at bruge KommandoCtrl + Skift + Enter frem for kun Enter).

I LibreOffice Calc-funktioner kan parametre markeret som "valgfri" kun udelades, hvis ingen parameter følger. I en funktion med for eksempel fire parametre, hvor de sidste to parametre er markeret som "valgfri", kan du udelade parameter 4 eller parametrene 3 og 4, men du kan ikke udelade parameter 3 alene.

Flere forklaringer øverst på denne side.

#### Eksempel

Denne funktion returnerer en matrix og håndteres på samme måde som de andre matrixfunktioner. Marker et område til svarene og derefter funktionen. Marker DataY. Hvis du vil, kan du indtaste andre parametre. Marker Matrix og klik på OK.

Hvis Statistik = 0, vil resultatet som minimum vise hældningen på regressionslinjen og dens skæringspunkt med Y-aksen. Hvis Statistik ikke er lig med 0, vises andre resultater.

### Andre LINREGR-resultater:

Undersøg følgende eksempler:

| A | B | C | D | E | F | G
1 | x1 | x2 | y |  | LINREGR-værdi |  |
2 | 4 | 7 | 100 |  | 4,17 | -3,48 | 82,33
3 | 5 | 9 | 105 |  | 5,46 | 10,96 | 9,35
4 | 6 | 11 | 104 |  | 0,87 | 5,06 | #IKKE.TILGÆNGELIG
5 | 7 | 12 | 108 |  | 13,21 | 4 | #IKKE.TILGÆNGELIG
6 | 8 | 15 | 111 |  | 675,45 | 102,26 | #IKKE.TILGÆNGELIG
7 | 9 | 17 | 120 |  |  |  |
8 | 10 | 19 | 133 |  |  |  |

Kolonne A indeholder flere X1 værdier, kolonne B flere X2 værdier og kolonne C Y-værdierne. Du har allerede indtastet disse værdier i dit regneark. Du har nu konfigureret E2:G6 i regnearket og aktiveret Funktionsguiden. For at få LINREGR-funktion til at virke, skal du have markeret afkrydsningsfeltet Matrix i Funktionsguiden. Marker herefter de følgende værdier i regnearket (eller indtast dem ved brug af tastaturet):

DataY er C2:C8

DataX er A2:B8

Linjetype og Statistik er begge sat til 1.

Så snart du klikker OK, vil LibreOffice Calc fylde eksemplet ovenfor med LINREGR-værdier som vist i eksemplet.

Formlen i Formellinjen svarer til hver celle af LINREGR-matricen {=LINREGR(C2:C8;A2:B8;1;1)}

Dette repræsenterer de beregnede LINREGR-værdier:

E2 og F2: Hældning m på regressionslinjen y=b+m*x for x1- og x2-værdierne. Værdierne er givet i omvendt rækkefølge. Det vil sige hældningen for x2 i E2 og hældningen for x1 i F2.

G2: Skæringspunkt b med y-aksen.

E3 og F3: standardafvigelsen for hældningens værdi.

G3: standardafvigelsen for skæringen.

E4: FORKLARINGSGRAD = R^2

F4: standardafvigelsen for regressionen beregnet for Y-værdien.

E5: F-værdien fra variansanalysen.

F5: Frihedsgraderne fra variansanalyserne.

E6: summen af den kvadrerede afvigelse på de estimerede Y-værdier fra deres lineær middelværdi.

F6: summen af den kvadrerede afvigelse på den estimerede Y-værdi fra de givne Y værdier.

Flere forklaringer øverst på denne side.

## LOGREGR (på engelsk: LOGEST)

Denne funktion beregner justeringen af de indtastede data som en eksponentiel regressionskurve (y=b*m^x).

#### Syntaks

LOGREGR( Data Y [; Data X [; Funktionstype [; Statistik]]])

DataY repræsenterer matricen med Y-data.

DataX (valgfri) repræsenterer matricen med X-data.

Funktionstype (valgfri). Hvis Funktionstype = 0, vil funktioner på formen Y = m^X blive beregnet. Ellers bliver Y = B*m^X funktioner beregnet.

Statistik (valgfri). Hvis Statistik=0, bliver kun regressionskoefficienten beregnet.

I LibreOffice Calc-funktioner kan parametre markeret som "valgfri" kun udelades, hvis ingen parameter følger. I en funktion med for eksempel fire parametre, hvor de sidste to parametre er markeret som "valgfri", kan du udelade parameter 4 eller parametrene 3 og 4, men du kan ikke udelade parameter 3 alene.

Flere forklaringer øverst på denne side.

#### Eksempel

Se LINREGR (på engelsk: LINEST). Dog vil der ikke blive returneret en kvadratsum.

## MDETERM (samme navn på engelsk)

Returnerer determinanten af en matrix. Denne funktion returnerer en værdi i den aktuelle celle; det er ikke nødvendige at definere et område til resultaterne.

#### Syntaks

MDETERM(Matrix)

Matrix repræsenterer en kvadratisk matrix, hvor determinanterne er defineret.

Du kan finde en generel introduktion til brug af matrixfunktioner øverst på denne side.

Flere forklaringer øverst på denne side.

## MENHED (på engelsk: MUNIT)

Returnerer den kvadratiske enhedsmatrix af en given størrelse. Enhedsmatricen er et kvadratisk område, hvor hoveddiagonalelementerne er lig med 1 og alle andre tabelelementer er lig med 0.

#### Syntaks

MENHED(Dimensioner)

Dimensioner henviser til størrelsen af områdeenheden.

Du kan finde en generel introduktion til matrixfunktioner øverst på denne side.

#### Eksempel

Vælg et kvadratisk område indenfor regnearket, for eksempel fra A1 til E5.

Vælg funktionen MENHED uden at afmarkere området. MarkÉr afkrydsningsfeltet Matrix. Indtast den ønskede dimension af enhedsmatricen, i dette tilfælde 5 og klik på OK.

Du kan også indtaste =MUNIT(5)-formlen i den sidste celle i det markerede område (E5) og trykke på Skift + Kommando + EnterSkift + Ctrl + Enter.

Nu ser du en enhedsmatrix med A1:E5.

Flere forklaringer øverst på denne side.

## MINVERT (på engelsk: MINVERSE)

Returnerer den inverse matrix.

#### Syntaks

MINVERT(Matrix)

Matrix repræsenterer en kvadratisk matrix, som skal inverteres.

Flere forklaringer øverst på denne side.

#### Eksempel

Vælg et kvadratisk område og vælg MINVERT. Marker matrix for uddata, marker feltet Matrix og klik på OK.

## MPRODUKT (på engelsk: MMULT)

Beregner matrixproduktet af to matricer. Antallet af kolonner i matrix 1 skal passe til antal rækker i matrix 2. Den kvadratiske matrix har samme antal rækker og kolonner.

#### Syntaks

MPRODUKT(Område 1; Område 2)

Område 1 repræsenterer den første matrix, der bruges i matrixproduktet.

Område 2 repræsenterer den anden matrix med det samme antal rækker.

Flere forklaringer øverst på denne side.

#### Eksempel

Vælg et kvadratisk område. Vælg funktionen MPRODUKT. Vælg Område 1, og derefter Område 2. Med Funktionsguiden markerer du afkrydsningsfeltet Område. Klik på OK. Output-området vises i det første markerede område.

## SUMPRODUKT (på engelsk: SUMPRODUCT)

Ganger tilsvarende elementer i den givne matrix og returnerer summen af disse produkter.

#### Syntaks

SUMPRODUKT(Matrix_ 1[; Matrix_ 2;][...;[Matrix_255]])

Matrix_ 1[; Matrix_ 2;][...;[Matrix_ 255]] repræsenterer matrixer, hvis tilsvarende elementer skal multipliceres.

I det mindste et matrix skal være en del af argumentlisten. Hvis kun et matrix er givet, lægges alle matrix-elementer sammen. Hvis der er givet mere end et matrix, skal de alle være af samme størrelse.

#### Eksempel

| A | B | C | D
1 | 2 | 3 | 4 | 5
2 | 6 | 7 | 8 | 9
3 | 10 | 11 | 12 | 13

=SUMPRODUKT(A1:B3; C1:D3) returnerer 397.

Beregning: A1*C1 + B1*D1 + A2*C2 + B2*D2 + A3*C3 + B3*D3

Du kan bruge SUMPRODUKT til beregning af skalarproduktet af to vektorer.

SUMPRODUKT returnerer et enkelt tal. Det er ikke nødvendigt at benytte funktionen som matrixfunktion.

Flere forklaringer øverst på denne side.

## SUMX2MY2 (samme navn på engelsk)

Returnerer summen af forskellen på kvadrater med tilsvarende værdier i to matricer.

#### Syntaks

SUMX2MY2(MatrixX; MatrixY)

MatrixX repræsenterer den første matrix, hvis elementer skal kvadreres og tilføjes.

MatrixY repræsenterer den anden matrix, hvis elementer skal kvadreres og fratrækkes.

Flere forklaringer øverst på denne side.

## SUMX2PY2 (samme navn på engelsk)

Returnerer summen af summen af kvadrater med tilsvarende værdier i to matricer.

#### Syntaks

SUMX2PY2(Matrix_X; Matrix_Y)

MatrixX repræsenterer den første matrix, hvis elementer skal kvadreres og tilføjes.

Matrix_Y repræsenterer den anden matrix, hvis elementer skal kvadreres og summeres.

Flere forklaringer øverst på denne side.

## SUMXMY2 (samme navn på engelsk)

Tilføjer kvadraterne af variationen mellem tilsvarende værdier i to matricer.

#### Syntaks

SUMXMY2(Matrix_X; Matrix_Y)

Matrix_X repræsenterer den første matrix, hvis elementer skal fratrækkes og kvadreres.

Matrix_Y repræsenterer den anden matrix, hvis elementer skal fratrækkes og kvadreres.

Flere forklaringer øverst på denne side.

## TENDENS (på engelsk: TREND)

Returnerer værdier langs en lineær tendens.

#### Syntaks

TENDENS(Data Y [; Data X [; Nye_Data X [; Lineær type]]])

DataY repræsenterer matricen med Y-data.

DataX (valgfri) repræsenterer matricen med X-data.

NyDataX (valgfri) repræsenterer den matrix af X-data, som bruges til genberegning af værdierne.

Linjetype (valgfri). Hvis Linjetype = 0, vil linjen blive beregnet gennem nulpunktet. Ellers vil der også blive beregnet forskydningslinjer. Standardværdien er Linjetype <> 0.

I LibreOffice Calc-funktioner kan parametre markeret som "valgfri" kun udelades, hvis ingen parameter følger. I en funktion med for eksempel fire parametre, hvor de sidste to parametre er markeret som "valgfri", kan du udelade parameter 4 eller parametrene 3 og 4, men du kan ikke udelade parameter 3 alene.

Flere forklaringer øverst på denne side.

#### Eksempel

Marker et regnearksområde, hvori tendensdata skal vises. Vælg funktionen. Indtast resultatområdet eller marker det med musen. Marker feltet Matrix. Klik på OK. De tendensdata, der er beregnet fra uddata, bliver vist.

## TRANSPONER (på engelsk: TRANSPOSE)

Transponerer rækkerne og kolonnerne i en matrix.

#### Syntaks

TRANSPONER(Matrix)

Matrix repræsenterer den matrix i regnearket, som skal transponeres.

Du kan finde en generel introduktion til brug af matrixfunktioner øverst på denne side.

#### Eksempel

Vælg det område i regnearket, hvor den transponerede tabel kan vises. Hvis originaltabellen har n rækker og m kolonner, skal dit markerede område have mindst m rækker og n kolonner. Indtast formlen direkte, markér originaltabellen og tryk på Skift + Kommando + EnterSkift + Ctrl + Enter. Hvis du bruger Funktionsguiden, kan du i stedet markere afkrydsningsfeltet Matrix. Den transponerede matrix vises i det markerede målområde og er automatisk beskyttet imod ændringer.

| A | B | C | D
1 | 2 | 3 | 4 | 5
2 | 6 | 7 | 8 | 9

Ovenstående tabel har to rækker og fire kolonner. For at transponere den, skal du vælge fire rækker og to kolonner. Antag at du vil transponere tabellen til området A7:B10 (fire rækker og to kolonner) skal du vælge hele området og indtaste følgende:

TRANSPONER(A1:D2)

Sørg derefter for at indtaste det som matrixformel med Skift + Kommando + EnterSkift + Ctrl + Enter. Resultatet vil være som følger:

| A | B
7 | 2 | 6
8 | 3 | 7
9 | 4 | 8
10 | 5 | 9

Relaterede emner

Funktioner efter kategori

Støt os venligst!